MkDatabase Statement:

The MkDatabase statement creates an empty Microsoft Access database. The required argument pathname must end in .mdb and reflects the location of where the new database will be created. MkDatabase can only create a database. An error occurs if the specified path is not found or if there is a database with the same name at the location specified in the pathname argument. Use the Kill Statement to delete an MS Access database.

Syntax:
MkDatabase pathname
Example Usage: 
<%
MkDatabase "C:\database.mdb"
%>
ASP Source Code: 
<%
Private Sub MkDatabase(byVal pathname)
	Dim objAccess, objFSO
	If LCase( Right( pathname, 4 ) ) <> ".mdb" Then
		Err.Raise 5155, "MkDatabase Statement", _
			  "Database name must end with '.mdb'"
		Exit Sub
	End If
	Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
	If objFSO.FileExists( pathname ) Then
		Set objFSO = Nothing
		Err.Raise 5155, "MkDatabase Statement", _
			  "Specified MS Access database already exists."
		Exit Sub
	End If
	Set objFSO = Nothing
	On Error Resume Next
	Set objAccess = CreateObject("Access.Application")
	If Err Then 
		On Error GoTo 0
		Err.Raise 5155, "MkDatabase Statement", _
			  "MS Access is not installed on this server."
		Exit Sub
	End If
	With objAccess
		.Echo False
		.NewCurrentDatabase pathname
		.CloseCurrentDatabase
		.Quit
	End With
	Set objAccess = Nothing
	On Error GoTo 0
End Sub
%>